Name: dkR10014 Date: 07/09/2001



The JCK-1.4 test
vm/instr/astore_w/astore_w004/astore_w00401m1/astore_w00401m1.html
executed in 64-bit mode causes crash of HotSpot VM (JDK build
1.4.0-beta_refresh-b70). The test fails with "Segmentation Fault".

To reproduce the issue execute the following test (class file is attached).
Test tries to store null reference into local variable 65534.

------------ astore_w00401m1.jasm ------------------------
public class astore_w00401m1 {

public static Method run:"([Ljava/lang/String;Ljava/io/PrintStream;)I"
    stack 3 locals 3
{
        try t7, t10;
        invokestatic Method run1:"()I";
        istore_2;
        endtry t7, t10;
        goto L10;
        catch t7 java/lang/StackOverflowError;
        astore_2;
        goto L10;
        catch t10 java/lang/OutOfMemoryError;
        astore_2;

  L10: iconst_0;
        ireturn;

}

public static Method run1:"()I"
    stack 2 locals 65535
{
        aconst_null;
        astore_w 65534;
        iconst_0;
        ireturn;
}


public static Method main:"([Ljava/lang/String;)V"
    stack 2 locals 2
{
        aload_0;
        getstatic Field java/lang/System.out:"Ljava/io/PrintStream;";
        invokestatic Method run:"([Ljava/lang/String;Ljava/io/PrintStream;)I";
        bipush 95/*STATUS_TEMP*/;
        iadd;
        invokestatic Method java/lang/System.exit:"(I)V";
        return;
}

} // end Class astore_w00401m1

------------ Logs ----------------------------------------
%jasm astore_w00401m1.jasm
%
% java -d64 -version
java version "1.4.0-beta_refresh"
Java(TM) 2 Runtime Environment, Standard Edition (build 1.4.0-beta_refresh-b70)
Java HotSpot(TM) 64-Bit Server VM (build 1.4.0-beta_refresh-b70, mixed mode)
%
% java -d64 -Xfuture astore_w00401m1
Segmentation Fault

----------------------------------------------------------

======================================================================